視頻教程：《運動控制器RTEX總線使用入門》

　　             運動控制器RTEX總線使用入門    

        　　01 準備工作    

        　　一、材料準備    

　　1.硬件

　　A.ZMC460N控制器一臺，帶RTEX總線接口。

　　B.松下RTEX伺服驅動器+電機一套。

　　C.電腦一臺。

　　D.帶屏蔽層網線若干。

　　E.24V直流電源一個。

　　F.接線端子與連接線若干。

　　2.軟件

　　A.ZDevelop V3.10版本控制器編程軟件。

　　從正運動官網www.zmotion.com.cn下載壓縮包，解壓后直接運行應用程序，無需安裝。

　　B.松下伺服驅動器上位機調試軟件。

　　從松下官網下載后安裝。

　　             二、硬件接線    

　　1.控制器接線

　　控制器接口的用途參見下圖。

　　A.主電源：將控制器主電源接線端子上的E+24V端子接入24V直流電源正極，將EGND端子接入24V直流電源負極。

　　B.以太網EtherNET端口接線：使用一根網線將控制器的EtherNET端口與電腦的以太網口相連。

　　C.RTEX伺服驅動器與控制器接線：RTEX總線用于接松下RTEX伺服驅動器，RTEX的接線方法參見下方的配置圖。

　　RTEX總線需要接兩根線，TX為發送端、RX為接收端。TX需要連接至RX，RX需要連接至TX，所有的設備連接成一個回路，中間不允許斷開。

　　使用一根網線將控制器的RTEX總線的RX端口與伺服驅動器的TX端口相連，使用另一根網線將控制器的RTEX總線的TX端口與伺服驅動器的RX端口相連。

　　配置圖

　　連接多個RTEX驅動器時，控制器的TX端口與第一個伺服驅動器的RX端口相連，第一個伺服驅動器的TX端口再連接第二個驅動器的RX端口，以此類推，最后一個驅動器的TX端口連接到控制器的RX端口，構成完整的通訊回路。

　　設備編號和驅動器編號按連接順序自動從0開始編號，與EtherCAT總線編號規則相同。

　　2.驅動器接線

　　伺服驅動器與電機和編碼器的接線參見驅動器手冊，將驅動器接上電源。

　　             02 軟件連接方法    

　　             一、控制器與電腦網口通訊    

　　控制器與電腦可以通過串口或網口連接，下面以網口連接例展開說明。

　　先將控制器與電腦用網線連接好，接通控制器的電源，再打開ZDevelop編程軟件，點擊菜單欄“控制器”→“連接”，打開“連接到控制器”窗口。

　　通過“連接到控制器”窗口，可以快速查看本機IP，對比控制器與電腦是否處于同一網段。

　　IP地址列表下拉選擇時，會自動查找當前局域網可用的控制器IP地址(控制器上電POWER燈和RUN燈亮的時候就能查找到該控制器的IP地址)。

　　同一個網絡有多個控制器的時候，IP的下拉列表若沒有顯示目標控制器的IP地址，可以采取IP掃描來查看當前所有可用的控制器IP地址，掃描完成之后確定關閉此窗口，重新在IP下拉列表選擇。

　　選擇正確的IP地址，點擊連接之后，編程軟件與控制器連接成功，在線命令與輸出窗口打印信息提示。

　　控制器出廠的缺省IP地址為192.168.0.11，“連接到控制器”窗口能顯示出本機IP地址，請注意設置有線網卡與無線網卡各自的IP。電腦需要設置IP地址與控制器IP處于同一網段才能連接，即四段的前三段要相同，最后一段不同才能通訊。

　　若控制器與電腦不處于同一網段，則需要修改控制器或電腦其中之一的IP地址，使二者處于同一網段。

　　修改控制器IP地址需要先使用串口連接控制器，獲取控制器IP地址，然后修改本機IP或控制器IP使二者處于同一網段。

　　             二、驅動器軟件與驅動器通信    

　　修改驅動器參數先連接驅動器，可選USB線或WLAN連接驅動器，這里使用USB線連接電腦與驅動器端的X1端口，給驅動器上電，打開松下驅動器軟件PANATERM，彈出“選擇與驅動器通信”窗口，選擇與驅動器通過USB連接后，自動獲取到驅動器信息顯示在窗口內，點擊OK連接成功，就能與驅動器通信，讀取驅動器的參數設置，對驅動器參數進行變更。

　             　03 RTEX總線驅動器    

　             　參數設置    

　　             一、驅動器參數修改    

　　RTEX修改驅動器參數類似EtherCAT，一是采用松下驅動器軟件修改，二是使用指令修改，DRIVE_READ參數讀取、DRIVE_WRITE參數寫入，在總線開啟后再使用指令修改，伺服參數的功能與設置參見松下RTEX驅動器手冊描述。

　　語法：DRIVE_READ(參數,數據存儲到VR的位置)

　　語法：DRIVE_WRITE(參數,參數值)

　　             參數寫法：不同類型的參數讀寫語法不同    

　　參數分類*256+參數編號(Pr7.20=7*256+20)

　　參數=130，讀取鉗位的狀態,BIT0,BIT1表示兩個通道的狀態

　　參數=$10000+(ssid)讀取RTEX驅動器系統信息，字符串存儲在VRSTRING

　　參數=$20000+(報警功能碼)+($1000*索引)讀取報警信息

　　參數=$30000+(監視功能碼)+($1000*索引)讀取監視器信息

　　             指令讀寫參數示例:    

　　BASE(0) '選擇軸0對應的驅動器

　　DRIVE_WRITE(7*256+11,6) '寫Pr7.11參數為6

　　DRIVE_WRITE(0*256+0,1) '寫Pr0.00參數為1

　　DRIVE_READ(0*256+0) '讀Pr0.00參數的值

　　DRIVE_READ(0*256+0) AXIS(1) '讀Pr0.00參數的值,AXIS指定軸號，不指定讀取軸0

　　DRIVE_READ($10000+$01) '讀取廠商名，不指定存儲位置時，直接打印出來

　　             驅動器修改參數示例：    

　　電機的旋轉方向可以通過參數Pr0.00調整，可選擇CW為正方向或選擇CCW為正方向。下圖選擇CCW為正方向，即發送正方向的運動指令時，電機軸旋轉方向為逆時針。

　　參數修改完成之后，電機EEP按鈕，將修改的參數寫入驅動器的EEPROM里，給驅動器重新上電參數生效。

　　電機旋轉方向的定義：從負載側的軸端看，順時針為CW，逆時針為CCW。

　　PR0.00參數方向設置參考：

　　             二、電子齒輪比    

　　伺服電機電子齒輪比就是伺服對接收到的控制器脈沖頻率進行放大或者縮小，比值大于1就是放大，比值小于1就是縮小，比值等于1時電機接受脈沖數等于控制器發出脈沖數。

　　電子齒輪比通過Pr0.09與Pr0.10的比值確定，電子齒輪比=Pr0.09/Pr0.10。

　　計算公式：電機接收的實際脈沖數=控制器發送脈沖數*電子齒輪比

　　例如：控制器發出脈沖10000個，電子齒輪比分子設為1，分母設為2，電子齒輪比為0.5，那么伺服實際運行按照5000個脈沖來進行?？刂破靼l出脈沖10000個，電子齒輪比分子設為2，分母設為1，電子齒輪比為2，那么伺服實際運行按照20000個脈沖來進行。

　　松下RTEX驅動器電子齒輪的比值在1/1000-8000倍的范圍內有效，超出此范圍驅動器報錯。

　　電機旋轉一圈的指令脈沖數通過Pr0.08設置，如上圖設為10000，表示發送10000個脈沖能使電機旋轉一圈。

　　             三、通訊周期    

　　控制器的周期必須與驅動器周期一致才可以成功通訊，控制器周期出廠默認為1ms，通過升級固件修改控制器周期。

　　Rtex總線驅動器的通訊周期目前有2種，0.5ms和1ms，通過設置驅動器參數P7.20和P7.21選擇。

　　注意P7.21參數一定要設置為1，否則無法通訊。

　　驅動器的周期可以通過指令修改，也可以通過驅動器軟件找到上述參數直接修改。

　　             指令讀寫驅動器通訊周期示例：    

　　'讀取通訊周期，讀取的數據存儲在VR里

　　DRIVE_READ(7*256+20,0) 'Pr7.20=7*256+20，Rtex通訊周期：3-0.5ms，6-1ms

　　DRIVE_READ(7*256+21,1) 'Pr7.21=7*256+21，Rtex指令更新周期比：1

　　'修改通訊周期，修改完寫入EEPROM，重啟生效

　　DRIVE_WRITE(7*256+20,SERVO_PERIOD/1000*6) 'Pr7.20=7*256+20，Rtex通訊周期：3-0.5ms，6-1ms

　　DRIVE_WRITE(7*256+21,1) 'Pr7.21=7*256+21，Rtex指令更新周期比：1

　　DRIVE_WRITE(128,1) '寫EEPROM,修改完成后需要斷電

　　             驅動器軟件修改通訊周期示例：    

　　連接驅動器軟件，在參數窗口，找到參數分類7，修改Pr7.20和Pr7.21修改驅動器周期。

　　             四、驅動器IO映射    

　　驅動器IO映射需要先將DRIVE_PROFILE=1，表示帶驅動器IO映射(DRIVE_PROFILE=0不帶驅動器IO映射)，然后使用DRIVE_IO指令設置驅動器IO地址，映射的編號范圍不要與總線上的其他設備的IO編號重復。

　　映射完成，控制器就能通過映射的驅動器IO編號，操作驅動器IO電平。不映射無法通過控制器操作驅動器IO。

　　DRIVE_IO (軸號)=輸入輸出IO起始編號。

　　示例：

　　DRIVE_PROFILE(iAxis) = 1 '帶驅動器IO映射

　　DRIVE_IO(iAxis) = i_IoNum '設定驅動器輸入/輸出IO起始編號

　　驅動器的IO操作，打開參數窗口的參數分類4，對輸出輸出的進行設定。

　　             五、驅動器軸映射    

　　RTEX總線上連接的設備的設備號按照連接順序從0開始自動編號，驅動器編號也是按連接順序給驅動器設備自動從0開始編號的，只算總線上的驅動器設備，其他設備是沒有驅動器編號的。

　　RTEX總線上連接的驅動器需要使用指令映射驅動器的軸號，使用AXIS_ADDRESS 指令映射，映射完成之后才能使用BASE指令選擇驅動器軸號，發送脈沖，控制驅動器所連的電機運行。

　　軸映射寫在總線初始化程序中，總線掃描之后，開啟總線之前。

　　語法：AXIS_ADDRESS(軸號)=(槽位號<<16)+驅動器編號+1

　　單總線控制器的總線槽位號缺省為0，即只支持RTEX總線的控制器，RTEX從槽位號是0。使用ZMC460N時，由于是雙總線控制器，EtherCAT總線槽位號為0，RTEX的槽位號為1。軸號為驅動器映射的目標軸號，映射時每個驅動器的軸號不重復，指向空閑軸號即可。

　　示例：

　　'單總線RTEX槽位號填0，雙總線RTEX槽位號為1。

　　AXIS_ADDRESS (6)=(1<<16)+0+1 '第一個RTEX驅動器，驅動器編號0，綁定為軸6

　　AXIS_ADDRESS (7)=(1<<16)+1+1 '第二個RTEX驅動器，驅動器編號1，綁定為軸7

　　AXIS_ADDRESS (8)=(1<<16)+2+1 '第三個RTEX驅動器，驅動器編號2，綁定為軸8

　　ATYPE(6)=50 '設置為RTEX軸類型，50-位置 51-速度 52-轉矩

　　ATYPE(7)=50

　　ATYPE(8)=50

　　             六、驅動器控制模式    

　　RTEX總線的控制模式有三種，使用ATYPE指令設置，ATYPE=50位置模式，ATYPE=51速度模式，ATYPE=52力矩模式。

　　位置模式采用運動指令控制軸運動，速度和力矩模式采用DAC指令控制軸運動，速度與力矩模式下切換其他模式的時候先將DAC置0，再修改ATYPE的值，防止發生事故。

　　控制模式由參數Pr0.01設定，選擇0半閉環控制，此時可以使用ATYPE指令切換控制器的控制模式，例如位置、速度和力矩模式。

　　1.ATYPE=50位置模式

　　設置好軸參數，使用運動控制器指令控制電機運行。

　　2.ATYPE=51速度模式

　　速度模式下使用DAC指令設置電機的運行速度，并持續運行，此模式下不能使用運動指令，故無需設置軸參數，將DAC=0停止運行。

　　速度模式下若要切換模式，為防止事故，先將DAC置0后再使用ATYPE指令切換。

　　RTEX速度模式下，通過參數Pr7.25設定速度單位，值為0對應單位：r/min，值為1對應單位：指令單位/s。

　　速度模式使用DRIVE_READ讀取速度的單位，如下圖值為0，此時單位是r/min。DRIVE_READ讀取不填參數保存地址時直接打印出來。

　　3.ATYPE=52力矩模式

　　修改ATYPE切換到力矩模式之前，請先將驅動器參數Pr6.47的第一位置為0，關閉2自由度控制模式。

　　再通過參數Pr3.17設置速度限制，如下圖(參照松下Rtex手冊)。Pr3.17(速度限制選擇)的設定值是0時，通過Pr3.21設置速度限制，設定值是1時，可以通過SL_SW切換轉矩控制時的速度限制值。

　　DRIVE_WRITE指令設置參考：按軸號依次設置

　　DRIVE_WRITE(6*256+47,0) AXIS(0) 'Pr6.47設為0，關閉2自由度控制模式

　　DRIVE_WRITE(3*256+17,0) AXIS(0) 'Pr3.17速度限制選擇設為0，通過Pr3.21設置速度限制

　　DRIVE_WRITE(3*256+21,5000) AXIS(0) 'Pr3.21速度限制設為5000

　　DRIVE_READ指令讀取驅動器設置情況:

　　將所有參與運動的軸均按照以上參數設置完成，就可以切換力矩模式，使用DAC指令發送力矩控制電機持續運行，此模式下不能使用運動指令，故無需設置軸參數，將DAC=0停止運行。

　　力矩模式下若要切換模式，為防止事故，先將DAC置0后再使用ATYPE指令切換。

　　             七、驅動器回零    

　　RTEX總線可使用控制器提供的回零方式DATUM(mode)，mode模式值選擇查看ZBasic編程手冊的DATUM指令。RTEX總線也可以使用驅動器本身的回零模式。

　　驅動器本身回零使用DATUM(21,mode2)指令，mode2模式值要查驅動器手冊，mode2填入對應驅動器回零模式值，見下表松下驅動器提供的回零模式，注意此時的原點限位等信號要接在驅動器上，并使用指令設置這些特殊信號對應的IO口，所以要使用驅動器回零時需要對驅動器的IO進行映射。

　　語法：DATUM(21,$11) '按驅動器當前回零模式開始回零

　　RTEX總線驅動器回零模式

　　             八、驅動器報警    

　　觀察驅動器上LED面板上是否有報錯信息，報錯會顯示錯誤碼，根據驅動器手冊排查錯誤，修正后將報警清零。

　　若控制器連接了ZDevelop軟件，驅動器報錯時，AXISSTATUS軸狀態提示錯誤信息。

　　打開驅動器軟件的報警窗口，也能看當前驅動器是否有警報，或查詢歷史警報。

        　　04 RTEX總線    

　　             初始化程序    

　　             一、初始化程序    

　　RTEX總線上連接的電機需要編寫一段RTEX總線初始化程序來進行使能。使能之后的應用與脈沖電機一致，運動指令都是相同的。

　　初始化程序一般過程：

　　1.使用SLOT_SCAN掃描設備，判斷RETURN是否正確，未連接設備時會報錯。

　　2.通過NODE_INFO/ NODE_AXIS_COUNT等對設備類型、信息等進行判斷。

　　3.依次設置AIXS_ADDRESS，ATYPE，DRIVE_PROFILE，DRIVE_IO等。

　　4.SLOT_START啟動設備。

　　5.建立連接后主站和從站即可進行周期性數據交換。

　　RTEX初始化程序與EtherCAT總線初始化類似，初始化參考程序如下：

　　'***************************RTEX總線初始化

　　global CONST MAX_AXISNUM =60 '最大軸數

　　global CONST Bus_Slot = 1 '槽位號0(單總線控制器缺省0)

　　global CONST PUL_AxisStart = 0 '本地脈沖軸起始軸號

　　global CONST PUL_AxisNum = 0 '本地脈沖軸軸數量

　　global CONST Bus_AxisStart = 0 '總線軸起始軸號

　　global CONST Bus_NodeNum = 2 '總線配置節點數量,用于判斷實際檢測到的從站數量是否一致

　　global Bus_InitStatus '總線初始化完成狀態

　　Bus_InitStatus = -1

　　global Bus_TotalAxisnum '檢查掃描的總軸數

　　delay(3000) '延時3S等待驅動器上電，具體根據驅動器調整延時

　　?"總線通訊周期：",SERVO_PERIOD,"us"

　　Rtex_Init() '初始化RTEX總線

　　while (Bus_InitStatus = 0) '重新初始化

　    　Rtex_Init()

　　wend

　　end

　　'*******************************RTEX總線初始化********************************

　　'初始流程: slot_scan(掃描總線) -> 從站節點映射軸/io -> SLOT_START(啟動總線) -> 初始化成功

　　'*******************************************************************************

　　global sub Rtex_Init()

    　　local Node_Num,Temp_Axis

    　　RAPIDSTOP(2)

    　　for i=0 to MAX_AXISNUM - 1 '初始化還原軸類型

        　　AXIS_ENABLE(i) = 0

        　　atype(i)=0

        　　AXIS_ADDRESS(i) =0

        　　DELAY(10) '防止所有驅動器全部同時切換使能導致瞬間電流過大

　　next

　　Bus_InitStatus = -1

　　Bus_TotalAxisnum = 0

　　SLOT_STOP(Bus_Slot)

　　delay(200)

　　SLOT_SCAN(Bus_Slot) '掃描總線

　　if return then

    　　?"總線掃描成功","連接從站設備數："NODE_COUNT(Bus_Slot)

    　　if NODE_COUNT(Bus_Slot) <> Bus_NodeNum then '判斷總線檢測數量是否為實際接線數量

        　　?""

        　　?"掃描節點數量與程序配置數量不一致!" ,"配置數量:"Bus_NodeNum,"檢測數量："NODE_COUNT(Bus_Slot)

        　　Bus_InitStatus = 0 '初始化失敗。報警提示

        　　return

　　endif

　　'"開始映射軸號"

　　for Node_Num=0 to NODE_COUNT(Bus_Slot)-1 '遍歷掃描到的所有從站節點

    　　if NODE_AXIS_COUNT(Bus_Slot,Node_Num) <> 0 then '判斷當前節點是否有電機

        　　for j=0 to NODE_AXIS_COUNT(Bus_Slot,Node_Num)-1 '根據節點帶的電機數量循環配置軸參數(針對一拖多驅動器)

            　　Temp_Axis = Bus_AxisStart + Bus_TotalAxisnum '軸號按NODE順序分配

            　　'Temp_Axis = Dirve_Alias '軸號按驅動器設定的撥碼分配(一拖多需要特殊處理)

            　　'Sub_SetNodePara(Node_Num,Temp_Axis)

            　　if return = FALSE then

                　　Bus_InitStatus = 0 '通訊周期不匹配

                　　return

            　　endif

            　　base(Temp_Axis)

            　　AXIS_ADDRESS=(1<<16)+Bus_TotalAxisnum+1 '映射軸號

            　　ATYPE=50 '設置控制模式 50-位置 51-速度 52-轉矩

            　　disable_group(Temp_Axis) '每軸單獨分組

            　　Bus_TotalAxisnum=Bus_TotalAxisnum+1 '總軸數+1

        　　next

    　　endif

　　next

　　?"軸號映射完成","連接總軸數："Bus_TotalAxisnum

　　DELAY 200

　　SLOT_START(Bus_Slot) '啟動總線

　　if return then

　　wdog=1 '使能總開關

　　'?"開始清除驅動器錯誤"

　　for i= Bus_AxisStart to Bus_AxisStart + Bus_TotalAxisnum - 1

    　　BASE(i)

    　　    ' DRIVE_CLEAR(0)

    　　DELAY 50

    　　datum(0) '清除控制器軸狀態錯誤"

    　　DELAY 50

    　　'"軸使能"

    　　AXIS_ENABLE=1

　　next

　　Bus_InitStatus = 1

　　?"軸使能完成"

    　　'本地脈沖軸配置

    　　    for i = 0 to PUL_AxisNum - 1

                　　base(PUL_AxisStart + i)

                　　AXIS_ADDRESS = (-1<<16) + i

                　　ATYPE = 4

            　　next

            　　?"總線開啟成功"

        　　else

            　　?"總線開啟失敗"

            　　Bus_InitStatus = 0

        　　endif

    　　else

        　　?"總線掃描失敗"

        　　Bus_InitStatus = 0

    　　endif

　　end sub

　　'**********************************從站節點特殊參數配置********************************

　　'通過DRIVE_READ/DRIVE_WRITE修改從站參數(具體參數查看驅動器手冊)

　　'******************************************************************************************

　　global sub Sub_SetNodePara(iNode,Iaxis)

    　　base(Iaxis)

    　　vr(0) = 0

    　　vr(1) = 0

    　　DRIVE_READ(7*256+20,0) '(Pr7.20=7*256+20)Rtex通訊周期 3-0.5ms 6-1ms

    　　DRIVE_READ(7*256+21,1) '(Pr7.21=7*256+21)Rtex指令更新周期比 1

    　　if (vr(0)/6 *1000 <> SERVO_PERIOD) or (vr(1) <> 1) then '判斷驅動器周期和控制器周期是否匹配

        　　?"總線周期不匹配：","控制周期-",SERVO_PERIOD,"軸號-",Iaxis,"伺服周期-",(vr(0)/6 *1000*vr(1))

        　　'DRIVE_WRITE(7*256+20,SERVO_PERIOD/1000*6) '(Pr7.20=7*256+20)Rtex通訊周期 3-0.5ms 6-1ms

        　　'DRIVE_WRITE(7*256+21,1) '(Pr7.21=7*256+21)Rtex指令更新周期比 1

        　　'DRIVE_WRITE(128,1) '寫EEPROM,修改完成后需要斷電

        　　return FALSE

    　　endif

    　　return TRUE

　　end sub

        　　二、總線狀態查看    

　　總線狀態查看的前提是初始化操作成功，控制器與驅動器接線正確，否則無法查看以下信息。

　　1.在菜單欄“控制器”→“控制器狀態”窗口查看“槽位1節點”，單總線控制器查看“槽位0節點”。

　　2.還可以通過在線命令發送?*RTEX打印RTEX總線上的全部設備信息。

　　3.在菜單欄“調試”→“總線狀態診斷”打開如下窗口查看控制器所有總線槽位接口的設備信息。

　　實際運行效果參見視頻尾部演示部分。

　　《運動控制器RTEX總線使用入門》就講到這里。更多學習視頻及圖文詳解請關注我們的公眾號“正運動小助手”。

　　本文由正運動技術原創，歡迎大家轉載，共同學習，一起提高中國智能制造水平。文章版權歸正運動技術所有，如有轉載請注明文章來源。